//PICWrite PIC18F2550へのファーム書き込みツール
// CODEとCONFIGのみ対応。アドレスが0x300000以上ならCONFIGと判断。
// 書込み時はwコマンドの後、IntelHEXを送る。

// 端子設定
#define PGC 8
#define PGD 9

// wait time talbe ( 1uS以下は1uSに揃える)*/
#define P1 1
#define P2 1
#define P3 1
#define P4 1
#define P5 1
#define P6 1
#define P7 1
#define P8 1
#define P9 1000
#define P9A 5000
#define P10 100
#define P11 5000
#define P12 2
#define P12A 70
#define P13 1
#define P13A 70
#define P14 1
#define P15 2
#define P16 1
#define P17 1
#define P18 1
#define P19 1
#define P20 5

// Memory block code
#define CODETYPE 0
#define EEPROMTYPE 1
#define IDTYPE 2
#define CONFIGTYPE 3

// String sを数値(long)に変換する。
// 先頭が0xで始まるならHEX.数字で始まるならDEC
long s2l(String s) {
  int i;
  String h="0x";
  int hexf=0;
  long val=0;
  byte buf[16];
  
  // 先頭が0xで始まるならhexfを1にセットする。
  if ( 0 == h.compareTo(s.substring(0,2)) ) { hexf=1; }

  s.toLowerCase(); // 小文字に統一
  s.getBytes(buf,15); // ここからは文字列配列で処理
  
  for (i=hexf? 2:0; i<s.length(); i++ ) {

    if ( hexf )  {
      // HEXの場合
      val<<=4;
      if ('a' <= buf[i] ) {
        val += (buf[i]-'a'+10);
      } else {
        val += (buf[i]-'0');
      }
    } else {
      // 10進の場合
      val *=10;
      val += (buf[i]-'0');
    }
  }
  return val;
}

// String sを数値(long)に変換する。 HEX専用
long s2lh(String s) {
  int i;
  long val=0;
  byte buf[16];

  s.toLowerCase(); // 小文字に統一
  s.getBytes(buf,15); // ここからは文字列配列で処理
  
  for (i=0; i<s.length(); i++ ) {
    val<<=4;
    if ('a' <= buf[i] ) {
      val += (buf[i]-'a'+10);
    } else {
      val += (buf[i]-'0');
    }
  }
  return val;
}
// countで指定したビット数のデータをPICに送信する。
void sendbit( int data, int count ) {
  int d=data;
  int i;
  for (i=0; i<count; i++) {
    if ( d & 0x1 ) {
      digitalWrite( PGD , HIGH);
    } else {
      digitalWrite( PGD , LOW);
    }
    d = d >> 1;
    digitalWrite( PGC , HIGH );
    delayMicroseconds(P2);
    digitalWrite( PGC , LOW );
    delayMicroseconds(P2);
  }
}

// sendexec
void sendexec() {
  int i;
  digitalWrite( PGD , LOW);
  for ( i=0; i<3; i++ ) {
    digitalWrite( PGC , HIGH );
    delayMicroseconds(P2);
    digitalWrite( PGC , LOW );
    delayMicroseconds(P2);
  }
  digitalWrite( PGC , HIGH );
//delayMicroseconds(P9);
  delayMicroseconds(P9A); // 18F14K50
  digitalWrite( PGC , LOW );
//delayMicroseconds(P16);
  delayMicroseconds(P10); // 18F14K50
  
  for ( i=0; i<16; i++ ) {
    digitalWrite( PGC , HIGH );
    delayMicroseconds(P2);
    digitalWrite( PGC , LOW );
    delayMicroseconds(P2);
  }
}

// countで指定したビット数のデータをPICから読み出す。
int getbit(int count) {
  int val=0;
  int i;
  for ( i = 0; i < count; i++ ) {
    //val=val<<1;
    digitalWrite( PGC , HIGH );
    delayMicroseconds(P2);
    digitalWrite( PGC , LOW );
    //val+= (HIGH==(digitalRead(PGD)?1:0 << (count-1-i)) );
    if (digitalRead(PGD)==HIGH) {
      val+= 1<<i;
    }
    delayMicroseconds(P2);
  }
  return val;
}

// PICに1行送信。comand:4bit opr1:8bit opr2:8bit
void sendline(int command, int opr1, int opr2 ) {

  /*
  Serial.print("---");
  Serial.print(command,HEX);
  Serial.print(" ");
  Serial.print(opr1,HEX);
  Serial.print(" ");
  Serial.print(opr2,HEX);
  Serial.println("---");
  */
  
  sendbit(command,4);
  delayMicroseconds(P5);
  sendbit(opr1,8);
  sendbit(opr2,8);
  delayMicroseconds(P5);
}

// PICのアドレステーブルにaをセットする。
void addressSet(long a) {
  int upper = (a & 0xff0000) / 0x10000;
  int high  = (a & 0x00ff00) / 0x100;
  int low   = (a & 0x0000ff);
  
  // Address Set. 
  // 注意：下バイトから先に出力するのでデータが
  // 0x6ef8の場合0xf8,0x6eの順に記載する。
  sendline(0x0,upper,0x0e);
  sendline(0x0,0xf8,0x6e);
  sendline(0x0,high,0x0e);
  sendline(0x0,0xf7,0x6e);
  sendline(0x0,low,0x0e);
  sendline(0x0,0xf6,0x6e);

  digitalWrite(PGD,LOW);  
}

// １バイト読み出す。
int readByte() {
  sendbit(0x9, 4);
  delayMicroseconds(P5);
  sendbit(0x00, 8);
  pinMode(PGD, INPUT);
  delayMicroseconds(P6);
  return getbit(8);
  //pinMode(PGD, OUTPUT);
  //digitalWrite(PGD,LOW);
}

//読み出し関数
void read(long start , long len) {
  long l;
  String s;
  String v;
  //addressSet(0x300000);
  addressSet(start);
  
  for (l=0 ; l < len; l++ ) {
    if((start+l)%16==0) {
      Serial.print((start+l),HEX);
      Serial.print(":");
    }
    // 1バイト読んで2桁のHEXとしてプリント
    s=String(readByte(),HEX);
    v="0";
    if (s.length()==1) { v.concat(s); } else { v=s; }
    Serial.print(v);
    Serial.print(" ");
    // 16バイト毎に改行する。
    if ( (start+l) % 16 == 15) {
      Serial.println("");
    }
    pinMode(PGD, OUTPUT);
    digitalWrite(PGD,LOW);
  }    
}
// 消去
void bulkerase() {
    sendline(0x0,0x3c,0x0e);
    sendline(0x0,0xf8,0x6e);
    sendline(0x0,0x00,0x0e);
    sendline(0x0,0xf7,0x6e);
    sendline(0x0,0x05,0x0e);
    sendline(0x0,0xf6,0x6e);
    sendline(0xc,0x3f,0x3f);
    sendline(0x0,0x3c,0x0e);
    sendline(0x0,0xf8,0x6e);
    sendline(0x0,0x00,0x0e);
    sendline(0x0,0xf7,0x6e);
    sendline(0x0,0x04,0x0e);
    sendline(0x0,0xf6,0x6e);
    sendline(0xc,0x8f,0x8f);

    sendline(0x0,0x00,0x00);
    sendline(0x0,0x00,0x00);
    digitalWrite( PGD , LOW);

    delayMicroseconds(P11);
    delayMicroseconds(P10);
}

void error(int e) {
  switch (e) {
    case 1:
      Serial.println( "IntelHEX fils is broken.");
      Serial.println( "First charctor is not ':'");
    case 2:
      Serial.println( "IntelHEX fils is broken.");
      Serial.println( "Line length is unmatch.");
      break;
    case 3:
      Serial.println( "IntelHEX fils is broken.");
      Serial.println( "Checksum is unmatch.");
      break;
    default:
      Serial.println( "Unknown error.");
      break;
  }   
}

// DATA write
void writeLine(String data) {
  int i;
  int len;
  int high;
  int low;
  len=data.length();
  for ( i=0; i<len; i+=4 ) {
    high=s2lh( data.substring(i,i+2) );
    low=s2lh( data.substring(i+2,i+4) );
    if(len <= i+4 ) {
      sendline(0xf, high,low);
    } else {
      sendline(0xd, high,low);
    }
  }
  sendexec();
  //Serial.println("-------------\n");
}

// CONFIG write
void writeConfig(String data, long addr) {
  int i;
  int len;
  int high=0;
  int low=0;
  len=data.length();
  for ( i=0; i<len; i+=2 ) {
    if ( addr%2 ) {
      high=s2lh( data.substring(i,i+2) );
    } else {
      low=s2lh( data.substring(i,i+2) );
    }
    sendline(0xf, low,high);
  }
  sendexec();
  //Serial.println("-------------\n");
}

// 書き込み関数
int write() {
  String command;      // 1行分を格納。
  String tmps="x";     // エコーバック用
  unsigned int ofsadrs;// オフセットアドレス
  unsigned int rec;    // レコードタイプ
  String data;         // データ文字列
  unsigned int sum;    // チェックサムフィールドの値
  int checksum;        // 計算したチェックサム
  int c;               // 読み込んだ値の一時置き場
  int len;             // データバイト数フィールドの値
  long segment=0;      // 現在のセグメントアドレス
  long extaddress=0;   // 拡張リニアアドレス
  int i;
  int endf=0;
  long currentaddress=-1;
  long address;
  int type=-1;          // 0:CODE 1:EEPROM 2:ID 3:CONFIG  -1:initial
  int currenttype=-1;
  
  Serial.println();
  Serial.println("Write!");
  Serial.println("Send me intelhex text");
  
  // 書き込みモードにする。
  //sendline(0x0,0xa6,0x8e);
  //sendline(0x0,0xa6,0x9c);
  
  while(0 == endf) {
    // Intelhexデータを1行取り込む。
    command="";
    while(1){
      while( Serial.available() == 0 ) {}
      c = Serial.read();
      tmps[0]=c;
      Serial.print(tmps);//ECHOBACK
      if(c==0x0d) {
        break;
      } else {
        command.concat(tmps);
      }
    }
    Serial.println();
    //Serial.print("command=");Serial.println(command);
    // 先頭文字が:である事を確認。
    if ( ':' != command[0] ) {
      error(1);
      return -1;
    }

    // データ長フィールドの値と行の長さの一致確認。
    len=s2lh(command.substring(1,3));
    //Serial.print("len=");Serial.println(len,DEC);
    if (len*2+11 != command.length() ) {
      error(2);
      return -1;
    }
    // オフセットアドレス、レコードタイプ、データ、チェックサム取出し。
    ofsadrs=s2lh( command.substring(3,7) );
    rec=s2lh( command.substring(7,9) );
    data =command.substring(9,9u+len*2);
    sum=s2lh( command.substring(9+len*2,9+len*2+2) );

    //Serial.print("ofsadrs=");Serial.println(ofsadrs,HEX);
    //Serial.print("data=");Serial.println(data);
    //Serial.print("rec=");Serial.println(rec,DEC);

    // チェックサム計算
    checksum=0;
    for ( i=1; i<= 8+len*2; i+=2) {
      checksum+=s2lh(command.substring(i,i+2));
    }
    checksum %= 0x100;
    checksum=0x100-checksum;
    checksum %= 0x100;

    //Serial.print("Checksum ");
    //Serial.print(sum,HEX);
    //Serial.print(":");
    //Serial.println(checksum,HEX);

    // チェックサム一致確認。
    if (checksum != sum ) {
      error(3);
      return -1;
    }
    
    // レコードタイプ毎の処理。
    switch (rec) {
      case 0:
        address=extaddress*0x10000+segment*0x10+ofsadrs;
        if ( 0x300000 <= address ) {
          if (type!=CONFIGTYPE) {
            sendline(0x0,0xa6,0x8e);
            sendline(0x0,0xa6,0x8c);
            sendline(0x0,0xa6,0x84);  // 18F14K50
          }
          addressSet(address);
          writeConfig(data, address);
          type=CONFIGTYPE;
        } else { 
          if (type!=CODETYPE) {
            sendline(0x0,0xa6,0x8e);
            sendline(0x0,0xa6,0x9c);
            sendline(0x0,0xa6,0x84);  // 18F14K50
          }
          addressSet(address);
          writeLine(data);
          type=CODETYPE;
        }
        /*
        if ( address != currentaddress) {
          Serial.print("Address set ="); Serial.println(address,HEX);
          addressSet(address);
        }
        Serial.print("Write "); Serial.print(address,HEX);
        Serial.print(" to "); Serial.println(address+len,HEX);
        writeByte(data);
        currentaddress=address+len;
        Serial.print("Current "); Serial.println(currentaddress,HEX);
        */
        break;
      case 1:
        endf=1;
        break;
      case 2:
        segment=s2lh(data);
        break;
      case 3:
        break;
      case 4:
        extaddress=s2lh(data);
        break;
      case 5:
        break;
      default:
        break;
    }
  }
}

// 書き込み関数
int verify() {
  String command;      // 1行分を格納。
  String tmps="x";     // エコーバック用
  unsigned int ofsadrs;// オフセットアドレス
  unsigned int rec;    // レコードタイプ
  String data;         // データ文字列
  unsigned int sum;    // チェックサムフィールドの値
  int checksum;        // 計算したチェックサム
  int c;               // 読み込んだ値の一時置き場
  int len;             // データバイト数フィールドの値
  long segment=0;      // 現在のセグメントアドレス
  long extaddress=0;   // 拡張リニアアドレス
  int i;
  int endf=0;
  long address;
  int eval,rval;
  
  Serial.println();
  Serial.println("Verify!");
  Serial.println("Send me intelhex text");

  while(0 == endf) {
    // Intelhexデータを1行取り込む。
    command="";
    while(1){
      while( Serial.available() == 0 ) {}
      c = Serial.read();
      tmps[0]=c;
      Serial.print(tmps);//ECHOBACK
      if(c==0x0d) {
        break;
      } else {
        command.concat(tmps);
      }
    }
    Serial.println();
    // 先頭文字が:である事を確認。
    if ( ':' != command[0] ) {
      error(1);
      return -1;
    }

    // データ長フィールドの値と行の長さの一致確認。
    len=s2lh(command.substring(1,3));
    if (len*2+11 != command.length() ) {
      error(2);
      return -1;
    }
    ofsadrs=s2lh( command.substring(3,7) );
    rec=s2lh( command.substring(7,9) );
    data =command.substring(9,9u+len*2);
    sum=s2lh( command.substring(9+len*2,9+len*2+2) );

    // チェックサム計算
    checksum=0;
    for ( i=1; i<= 8+len*2; i+=2) {
      checksum+=s2lh(command.substring(i,i+2));
    }
    checksum %= 0x100;
    checksum=0x100-checksum;

    // チェックサム一致確認。
    if (checksum != sum ) {
      error(3);
      return -1;
    }
    
    // レコードタイプ毎の処理。
    switch (rec) {
      case 0:
        address=extaddress*0x10000+segment*0x10+ofsadrs;

        addressSet(address);
  for ( i=0 ; i< len; i++ ) {
          eval=s2lh(data.substring(i*2,i*2+2));
          rval=readByte();
          pinMode(PGD, OUTPUT);
          if ( eval != rval ) {
            Serial.println();
            Serial.println("Verify unmatch.");
            Serial.print( address+i, HEX);
            Serial.print( ": except:");
            Serial.print( eval, HEX);
            Serial.print( ": read:");
            Serial.println( rval, HEX);
            endf=1;
          }
        }
        break;
      case 1:
        endf=1;
        break;
      case 2:
        segment=s2lh(data);
        break;
      case 3:
        break;
      case 4:
        extaddress=s2lh(data);
        break;
      case 5:
        break;
      default:
        break;
    }
  }
}

// コマンドラインをフィールドに分ける。
// フィールド数を返す。
int commandLine( String s, String a[] ) {
    int cnt=0;
    int i;
    int f=0;
    
    s.trim();
    //Serial.println("s="+s);
    
    for (i =0 ; i < s.length(); i++ ) {
      if ( ' ' == s[i] ) {
        if(0 == f) {
          //Serial.print(cnt,DEC);Serial.print("=");
          //Serial.println(a[cnt]);
          cnt++;
          if ( cnt==16 ) return cnt;
        }
        f=1;
      } else {
        a[cnt].concat(s[i]);
        f=0;
      }
    }
    return cnt+1;
}


// 初期設定
void setup() {
  Serial.begin(9600);
  pinMode(PGC, OUTPUT);
  pinMode(PGD, OUTPUT);
  digitalWrite(PGC,LOW);
  digitalWrite(PGD,LOW);

}

// MAIN LOOP
void loop() {
  String command;
  int c,cc;
  long val1,val2;
  String commandArray[16];
  String tmps="x";
  
  Serial.println("");
  Serial.println(" r  <start address> <count>: read from PIC ");
  Serial.println(" e : all erase  ");
  Serial.println(" w : write to PIC ");
  Serial.println(" v : verify");

  //コマンド読み込み
  command="";
  while(1){
    while( Serial.available() == 0 ) {}
    c = Serial.read();
    tmps[0]=c;
    Serial.print(tmps);//SENDBACK
    if(c==0x0d || c==0x0a) {
      break;
    } else {
      command.concat(tmps);
    }
  }
  Serial.println();
  // コマンドラインをフィールドに分ける。ccはフィールド数。
  cc=commandLine(command,commandArray);

  // コマンド毎の処理
  switch (commandArray[0][0] ) {
    
  case 'r':
    if(cc!=3) break;
    val1=s2l(commandArray[1]);
    val2=s2l(commandArray[2]);
    read(val1, val2);
    break;

  case 'e':
    Serial.println();
    Serial.println("ALL Erase <y/n>?");
    while( Serial.available() == 0 ) {}
    c=Serial.read();
    if('y' != c) {break;}
    Serial.println();
    Serial.println("ALL Erase START!!"); 
    bulkerase();
    break;
    
  case 'w':
    write();
    break;

  case 'v':
    verify();
    break;
    
  default:
    break;
  }


}